¿Qué es el comando o la manera más rápida de los resultados de la producción de la consola utilizando vbscript?

InformationsquelleAutor Regmi | 2010-12-07

5 Comentarios

  1. 282

    Que significa:

    Wscript.Echo "Like this?"

    Si de ejecutar que bajo wscript.exe (el controlador predeterminado para el .vbs extensión, de forma que lo que vas a conseguir si hace doble clic en la secuencia de comandos) que obtendrá un «MessageBox» diálogo con el texto. Si usted ejecutar que bajo cscript.exe usted obtendrá una salida en la ventana de consola.

    • Usted puede utilizar directamente en el wscript.exe la función MsgBox("text") o MsgBox(object.property) pero Wscript.Echo es más fácil de escribir. Gracias.
    • Unintuitively para mí, WScript.Echo debe se utiliza para saber si se está ejecutando a través de la WScript o CScript. Es decir, no no una CScript.Echo, en caso de que el futuro de google es de extrañar. (Es feliz el msgboxes se han ido [cuando se ejecuta con cscript], sin embargo, gracias.)
    • Es posible hacer este cuadro de mensaje se cierra automáticamente después de 1 o 2 segundos? Quiero que se abrirá para notificar al usuario de lo que está pasando, pero luego se cierra automáticamente después de 1 seg.
    • No w/ el stock WScript.Echo. Supongo que, si quería permanecer totalmente dentro de WScript se podría hacer algo horrifyingly chunga como Exec ing fuera de otro proceso para hacer un «SendKeys» para que el proceso padre para cerrar el cuadro de mensaje.
    • En realidad, acabo de encontrar este popup método. Muy similar a echo pero le permite especificar un tiempo de espera después del cual se cerrará automáticamente la ventana emergente. Muy conveniente y fácil de usar: technet.microsoft.com/en-us/library/ee156593.aspx
  2. 57

    Yo sé que esto fue hace un tiempo, pero tal vez esto va a ayudar a los demás. Fue encontrada en Dragón-Scripts de TI y Repositorio de Código.

    Usted puede hacer esto con la siguiente y mantenerse alejado de la cscript/wscript diferencias y le permite obtener la misma salida de la consola que un archivo por lotes que tendría. Esto puede ayudar si tu llamado VBS desde un archivo por lotes y la necesidad de hacer que se vea perfecta.

    Set fso = CreateObject ("Scripting.FileSystemObject")
    Set stdout = fso.GetStandardStream (1)
    Set stderr = fso.GetStandardStream (2)
    stdout.WriteLine "This will go to standard output."
    stderr.WriteLine "This will go to error output."
    • Si el script se inicia haciendo doble clic sobre y lo abrió con wscript, el guión da un mensaje de error: «Identificador no Válido».
    • Usted está recibiendo este error si se ejecuta la secuencia de comandos utilizando wscript.exe. Wscript es windows orientado y no tiene la consola de corrientes. Uso cscript.exe lugar: technet.microsoft.com/en-us/library/bb490816.aspx
    • tiene un punto válido. El empuje de esta respuesta es que el uso de stdout directamente para evitar el CScript/WScript diferencias. Que es incorrecta. Esta solución sólo funciona bajo CScript.exe, por lo que no parece ser de mucho beneficio sobre el uso de WScript.Echo. De hecho, la diferencia se magnifica, porque la secuencia de comandos no se ejecutan en virtud de WScript. Es una técnica válida que tiene sus usos, por ejemplo, si uno tiene que escribir a StdErr, pero en el contexto de esta respuesta, es engañosa.
    • Sólo quiero a la luz de la ventaja de este método sobre WScript.Echo: cscript //b foobar.vbs Ejecuta foobar.vbs sin salida de la consola, pero por Rob método puede tener una salida incluso cuando se pasa \\b a cscript.exe
  3. 19

    Sólo se necesita fuerza cscript lugar wscript. Yo siempre uso esta plantilla. La función ForceConsole() se ejecute su vbs en cscript, también se han agradable alias para imprimir y escanear texto.

     Set oWSH = CreateObject("WScript.Shell")
     vbsInterpreter = "cscript.exe"
    
     Call ForceConsole()
    
     Function printf(txt)
        WScript.StdOut.WriteLine txt
     End Function
    
     Function printl(txt)
        WScript.StdOut.Write txt
     End Function
    
     Function scanf()
        scanf = LCase(WScript.StdIn.ReadLine)
     End Function
    
     Function wait(n)
        WScript.Sleep Int(n * 1000)
     End Function
    
     Function ForceConsole()
        If InStr(LCase(WScript.FullName), vbsInterpreter) = 0 Then
            oWSH.Run vbsInterpreter & " //NoLogo " & Chr(34) & WScript.ScriptFullName & Chr(34)
            WScript.Quit
        End If
     End Function
    
     Function cls()
        For i = 1 To 50
            printf ""
        Next
     End Function
    
     printf " _____ _ _           _____         _    _____         _     _   "
     printf "|  _  |_| |_ ___ ___|     |_ _ _ _| |  |   __|___ ___|_|___| |_ "
     printf "|     | | '_| . |   |   --| | | | . |  |__   |  _|  _| | . |  _|"
     printf "|__|__|_|_,_|___|_|_|_____|_____|___|  |_____|___|_| |_|  _|_|  "
     printf "                                                       |_|     v1.0"
     printl " Enter your name:"
     MyVar = scanf
     cls
     printf "Your name is: " & MyVar
     wait(5)
    • ¿Estás seguro de que responde a la pregunta?
    • Sí, sólo llame a la ForceConsole() y, a continuación, utilizar printf() para imprimir el texto en la consola de salida. También tiene otros alias para borrar la pantalla, leer un texto y esperar (el sueño)
  4. 6

    Me encontré con este post y se fue de nuevo a un método que he utilizado hace algún tiempo que es similar a la de @MadAntrax del.

    La principal diferencia es que utiliza un VBScript clase definida por el usuario para envolver toda la lógica de conmutación a CScript y salida de texto a la consola, por lo que hace el script principal un poco más limpio.

    Esto supone que su objetivo es transmitir la salida a la consola, en lugar de tener salida de ir a cuadros de mensaje.

    La cCONSOLE clase está por debajo. Para usarlo, incluyen la clase completa al final de la secuencia de comandos y, a continuación, crear una instancia a la derecha en el comienzo de la secuencia de comandos. Aquí está un ejemplo:

        Option Explicit
    
    '//Instantiate the console object, this automatically switches to CSCript if required
    Dim CONS: Set CONS = New cCONSOLE
    
    '//Now we can use the Consol object to write to and read from the console
    With CONS
    
        '//Simply write a line
         .print "CSCRIPT Console demo script"
    
         '//Arguments are passed through correctly, if present
         .Print "Arg count=" & wscript.arguments.count
    
         '//List all the arguments on the console log
         dim ix
         for ix = 0 to wscript.arguments.count -1
            .print "Arg(" & ix & ")=" & wscript.arguments(ix)
         next
    
         '//Prompt for some text from the user
         dim sMsg : sMsg = .prompt( "Enter any text:" )
    
         '//Write out the text in a box
         .Box sMsg
    
         '//Pause with the message "Hit enter to continue"
         .Pause
    
    End With     
    
    
    
    
    '= =========== End of script - the cCONSOLE class code follows here

    Aquí está el código para el cCONSOLE clase

         CLASS cCONSOLE
    '= =================================================================
    '= 
    '=    This class provides automatic switch to CScript and has methods
    '=    to write to and read from the CSCript console. It transparently
    '=    switches to CScript if the script has been started in WScript.
    '=
    '= =================================================================
    Private oOUT
    Private oIN
    Private Sub Class_Initialize()
    '= Run on creation of the cCONSOLE object, checks for cScript operation
    '= Check to make sure we are running under CScript, if not restart
    '= then run using CScript and terminate this instance.
    dim oShell
    set oShell = CreateObject("WScript.Shell")
    If InStr( LCase( WScript.FullName ), "cscript.exe" ) = 0 Then
    '= Not running under CSCRIPT
    '= Get the arguments on the command line and build an argument list
    dim ArgList, IX
    ArgList = ""
    For IX = 0 to wscript.arguments.count - 1
    '= Add the argument to the list, enclosing it in quotes
    argList = argList & " """ & wscript.arguments.item(IX) & """"
    next
    '= Now restart with CScript and terminate this instance
    oShell.Run "cscript.exe //NoLogo """ & WScript.ScriptName & """ " & arglist
    WScript.Quit
    End If
    '= Running under CScript so OK to continue
    set oShell = Nothing
    '= Save references to stdout and stdin for use with Print, Read and Prompt
    set oOUT = WScript.StdOut
    set oIN = WScript.StdIn
    '= Print out the startup box 
    StartBox
    BoxLine Wscript.ScriptName
    BoxLine "Started at " & Now()
    EndBox
    End Sub
    '= Utility methods for writing a box to the console with text in it
    Public Sub StartBox()
    Print "  " & String(73, "_") 
    Print " |" & Space(73) & "|"
    End Sub
    Public Sub BoxLine(sText)
    Print Left(" |" & Centre( sText, 74) , 75) & "|"
    End Sub
    Public Sub EndBox()
    Print " |" & String(73, "_") & "|"
    Print ""
    End Sub
    Public Sub Box(sMsg)
    StartBox
    BoxLine sMsg
    EndBox
    End Sub
    '= END OF Box utility methods
    '= Utility to center given text padded out to a certain width of text
    '= assuming font is monospaced
    Public Function Centre(sText, nWidth)
    dim iLen
    iLen = len(sText)
    '= Check for overflow
    if ilen > nwidth then Centre = sText : exit Function
    '= Calculate padding either side
    iLen = ( nWidth - iLen ) / 2
    '= Generate text with padding
    Centre = left( space(iLen) & sText & space(ilen), nWidth )
    End Function
    '= Method to write a line of text to the console
    Public Sub Print( sText )
    oOUT.WriteLine sText
    End Sub
    '= Method to prompt user input from the console with a message
    Public Function Prompt( sText )
    oOUT.Write sText
    Prompt = Read()
    End Function
    '= Method to read input from the console with no prompting
    Public Function Read()
    Read = oIN.ReadLine
    End Function
    '= Method to provide wait for n seconds
    Public Sub Wait(nSeconds)
    WScript.Sleep  nSeconds * 1000 
    End Sub
    '= Method to pause for user to continue
    Public Sub Pause
    Prompt "Hit enter to continue..."
    End Sub
    END CLASS
  5. 3

    Hay cinco maneras de texto de salida para la consola:

    Dim StdOut : Set StdOut = CreateObject("Scripting.FileSystemObject").GetStandardStream(1)
    WScript.Echo "Hello"
    WScript.StdOut.Write "Hello"
    WScript.StdOut.WriteLine "Hello"
    Stdout.WriteLine "Hello"
    Stdout.Write "Hello"

    WScript.Eco de la salida de la consola, pero sólo si la secuencia de comandos se inicia con cscript.exe. Es la salida a los cuadros de mensaje si empezamos a utilizar wscript.exe.

    WScript.StdOut.Escribir y WScript.StdOut.WriteLine siempre que la salida a la consola.

    StdOut.Escribir y StdOut.WriteLine también siempre que la salida a la consola. Se requiere la creación de objetos, pero es de alrededor del 10% más rápido que WScript.Eco.

    • … y como dice en un comentario a las respuestas anteriores, esto no funciona cuando se ejecuta con wscript.exe: stackoverflow.com/questions/4388879/…
    • También se encontró una explicación acerca de GetStandardStream() vs WScript.StdIn/.StdOut/.StdErr : «VBScript en pocas palabras: Un Escritorio de Referencia Rápida (2ª Edición)» books.google.fr/books?id=NLpuZSatG3QC página 298 dice que es «functionnaly equivalente».

Dejar respuesta

Please enter your comment!
Please enter your name here