Estoy atascado con un sumif fórmula. Creo que si utilizan alguna combinación de indice y coincidir que yo pudiera llegar a funcionar, pero he sido incapaz de hacerlo para la última hora!

Necesito suma de una tabla de números en función de el número de la casa y 2 fechas. Por ejemplo, necesito sumar los números para casa de 1 entre las fechas 08-05-17 y 13-05-17.

Mi anterior experiencia con el indice y coincidir es que sólo he cada utilizado para obtener un solo dígito.

Excel - SUMIF INDICE y COINCIDIR

Excel - SUMIF INDICE y COINCIDIR

InformationsquelleAutor Bake.G | 2017-05-27

4 Comentarios

  1. 3

    OFFSET e INDIRECTOS son volátiles, esto es posible con ÍNDICE/PARTIDO

    =SUMIFS(INDEX(Sheet1!$W:$AC,MATCH("House " & B4,Sheet1!$A:$A,0),0),Sheet1!$W$3:$AC$3,"<=" & $AE4,Sheet1!$W$3:$AC$3,">=" & $AD4)
    

    La 0 como el tercer criterio en el ÍNDICE de retorno de todas las columnas en la fila elegida por el PARTIDO.

    Esta fórmula es no volátil y no de la matriz.

    • Me ganó por un par de minutos! aquí
    • Como un aparte, yo iba a sugerir poner 1 a 6 en A4:A9 y fortmatting la célula como \Hou\s\e 0. Esto eliminaría la concatenación de cadenas en el PARTIDO.
    • Pensé que le dio cuatro horas de head start. 🙂 @Jeeped
    • Esta respuesta funcionó a la perfección! Yo quería seguir con el índice y el partido en lugar de offset e indirectos. Saludos
  2. 0

    Modificar los siguientes

    =SUMIFS(OFFSET(B3:ZZ3,MATCH("house 1",E:E,0)-3,0),B3:ZZ3,">"&42863,B3:ZZ3,"<"&42868)
    

    Cambio «casa 1» a una referencia.

    Cambio 42863 y 42868 a las referencias de la fecha de inicio y finalización, respectivamente. (los números son sólo la fecha en formatos de número.)

    Cambio 3s en los rangos y el partido fórmula para el número de fila que contiene las fechas.

    cambio B3:ZZ3 para el rango de filas de su fecha. Suponiendo que usted está actualizando los datos en una base continua, puede dar espacio mediante el aumento de la gama, como en mi ejemplo a la columna ZZ.

  3. 0

    Suponiendo que:

    • Primera tabla está en la Hoja1
    • Casa 1 datos de la primera tabla está en la fila 4
    • Segunda tabla en una hoja aparte
    • Casa 1 datos de la segunda tabla está en la fila 4

    Esta fórmula en la Hoja2, celular AG4 debería funcionar:

    SUM(INDIRECT("Sheet1!R4C"&22+MATCH(AD4,Sheet1!W3:AC3,0),FALSE):INDIRECT("Sheet1!R4C"&22+MATCH(AE4,Sheet1!W3:AC3,0),FALSE))
    
  4. 0

    Fórmula para AI4 el uso de matrices de manipulación (fórmula normal, aunque, no CSE):

    =SUMPRODUCT(Sheet1!W4:XX100*
      (Sheet1!A4:A100 = "House " & A4)*
      (Sheet1!W3:XX3 >= AD4)*
      (Sheet1!W3:XX3 <= AE4))
    

    p.s. Index/Match versión debe ser (supuestamente) más rápido, Pero me gusta este formulario para su legibilidad…

Dejar respuesta

Please enter your comment!
Please enter your name here